Aquarium Control & Monitoring

Controlling lights and CO2 admission to a aquarium. Sensor data is stored so it can be used for statistics.

Feb 24, 2019

•

40196 views

•

14 respects

arduino

aquarium

nodejs

Components and supplies

RTC Module

9V 1A Switching Wall Power Supply

Resistor 10k ohm

Metalic Case

Resistor 4.7k Ohm

DHT22 Temperature Sensor

Arduino UNO

Infrared Module (Generic)

Capacitor 10 µF

Single Turn Potentiometer- 10k ohms

Adafruit Waterproof DS18B20 Digital temperature sensor

Breadboard (generic)

RGB Backlight LCD - 16x2

2-Channel SPDT Relay Carrier with 5VDC Relays

Tools and machines

Mastech MS8217 Autorange Digital Multimeter

Hot glue gun (generic)

Soldering iron (generic)

Project description

Code

Aquarium server

no description/ Read More

Latest commit to the master branch on Invalid date

Download as a zip

Sketch File

arduino

1#include "RTClib.h"
2#include <Time.h>
3#include <TimeAlarms.h>
4#include  <DHT.h>
5#include <OneWire.h> 
6#include <DallasTemperature.h>
7#include <LiquidCrystal.h>
8#include  <EEPROM.h>
9#include "IRremote.h"
10
11// RTC
12RTC_DS1307 rtc;
13
14//  DHT humidity senzor
15#define DHTPIN 10     // what pin we're connected to
16#define  DHTTYPE DHT22   // DHT 22  (AM2302)
17DHT dht(DHTPIN, DHTTYPE); //// Initialize  DHT sensor for normal 16mhz Arduino
18
19// Water proof senzor DS18B20
20#define  ONE_WIRE_BUS 13
21OneWire oneWire(ONE_WIRE_BUS);
22DallasTemperature sensors(&oneWire);
23
24//  LCD screen
25LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
26byte degSymbol[8] = {
27  B11100,
28  B10100,
29  B11100,
30  B00000,
31  B00000,
32  B00000,
33  B00000,
34};
35int  lcdPage = 0;
36
37// IR
38int irPin = 6;
39IRrecv irrecv(irPin);
40decode_results  irResults;
41long irKey = 0;
42
43// Serial read globals
44char rx_byte = 0;
45String  key = "";
46bool isKey = false;
47String value = "";
48bool isValue = false;
49
50//  Aquarium LED default values
51int led1OnH = 8;
52int led1OnM = 30;
53int led1OffH  = 12;
54int led1OffM = 30;
55int led2OnH = 18;
56int led2OnM = 30;
57int led2OffH  = 20;
58int led2OffM = 0;
59
60int led1OnHAddress = 0;
61int led1OnMAddress  = 1;
62int led1OffHAddress = 2;
63int led1OffMAddress = 3;
64int led2OnHAddress  = 4;
65int led2OnMAddress = 5;
66int led2OffHAddress = 6;
67int led2OffMAddress  = 7;
68
69// Aquarium CO2 default values
70int co2OnH = 7;
71int co2OnM = 0;
72int  co2OffH = 21;
73int co2OffM = 0;
74
75int co2OnHAddress = 8;
76int co2OnMAddress  = 9;
77int co2OffHAddress = 10;
78int co2OffMAddress = 11;
79
80// Aquarium  options
81bool ledAuto = true;
82bool co2Auto = true;
83bool co2On = false;
84bool  ledOn = false;
85
86// Aquarium status
87float aquariumTemp;
88
89// Ambient  status
90float ambientTemp, ambientHum;
91
92// Status send to DB every 15 mins
93int  statusSendMinutes = 20;
94
95// Alarms
96AlarmID_t led1OnAlarm = 0;
97AlarmID_t  led1OffAlarm = 0;
98AlarmID_t led2OnAlarm = 0;
99AlarmID_t led2OffAlarm = 0;
100AlarmID_t  co2OnAlarm = 0;
101AlarmID_t co2OffAlarm = 0;
102
103// Relay pins
104int relayLed  = 7;
105int relayCo2 = 8;
106
107void setup() {
108  pinMode(relayLed, OUTPUT);
109  pinMode(relayCo2, OUTPUT);
110
111  // Use only without RTC
112  // setTime(10,19,0,16,2,19);
113
114  Serial.begin(9600);
115  dht.begin();
116  sensors.begin();
117
118  lcd.createChar(0,  degSymbol);
119  lcd.begin(16, 2);
120
121  // Start Ir reciever
122  irrecv.enableIRIn();  // Start the receiver
123
124  if (! rtc.begin()) {
125    Serial.println("Couldn't  find RTC");
126    while (1);
127  }
128
129  if (! rtc.isrunning()) {
130    Serial.println("RTC  is NOT running!");
131  }
132
133  // Sync time lib with RTC
134  setSyncProvider(getRTCTime);
135  setSyncInterval(60 * 60 * 4);
136
137  // should run only once at initial setup
138  // writeSettingsFromMemory();
139
140  readSettingsFromMemory();
141  updateLedState();
142  updateCo2State();
143  updateRelay();
144  sendStatus();
145
146  setAlarms();
147  Alarm.timerRepeat(60 * statusSendMinutes, sendStatus);
148  Alarm.timerRepeat(60,  updateLcd);
149}
150
151void loop() {
152  while(Serial.available()){
153    //  Read seril data and create key values pairs
154    rx_byte = Serial.read();
155
156    if (rx_byte != '\n') {
157      if (rx_byte == '$') {
158        isValue =  false;
159        isKey = true;
160        continue;
161      }
162      if (rx_byte  == '=') {
163        isValue = true;
164        isKey = false;
165        continue;
166      }
167      if (rx_byte == '&') {
168        setData();
169
170        value  = "";
171        key = "";
172        isValue = false;
173        isKey = false;
174        continue;
175      }
176
177      if (!isKey) {
178        value += rx_byte;
179      } else {
180        key += rx_byte;
181      }
182    } else {
183      if  (isValue) {
184        setData();
185
186        if (key != "" && key != "ledOn"  && key != "co2On") {
187          updateLedState();
188          updateCo2State();
189          updateAlarms();
190          updateRelay();
191        }
192      }
193
194      value = "";
195      key = "";
196      isKey = false;
197      isValue  = false;
198      sendStatus();
199    }
200  }
201
202  // IR remote loop
203  if  (irrecv.decode(&irResults)) {
204    dumpIR(&irResults);
205
206    irrecv.resume();  // Receive the next value
207//    Serial.println(irKey, HEX);
208//    Serial.println();
209
210    if (irKey == 16720605) {
211      toggleLed();
212    } else if (irKey == 16712445)  {
213      toggleCo2();
214    } else if (irKey == 16724175) {
215      loopLcdPage(-1);
216    } else if (irKey == 16743045) {
217      loopLcdPage(1);
218    }
219  }
220
221  Alarm.delay(1000);
222}
223
224void dumpIR(decode_results *irResults) {
225  int  count = irResults->rawlen;
226  irKey = irResults->value;
227}
228
229
230void setAlarms()  {
231  led1OnAlarm = Alarm.alarmRepeat(led1OnH, led1OnM, 20, LedOn);
232  led1OffAlarm  = Alarm.alarmRepeat(led1OffH, led1OffM, 20, LedOff);
233
234  if (led2OnH != 0)  {
235    led2OnAlarm = Alarm.alarmRepeat(led2OnH, led2OnM, 20, LedOn);
236    led2OffAlarm  = Alarm.alarmRepeat(led2OffH, led2OffM, 40, LedOff);
237  }
238
239  co2OnAlarm  = Alarm.alarmRepeat(co2OnH, co2OnM, 40, Co2On);
240  co2OnAlarm = Alarm.alarmRepeat(co2OffH,  co2OffM, 40, Co2Off);
241}
242
243void updateAlarms() {
244  Alarm.free(led1OnAlarm);
245  Alarm.free(led1OffAlarm);
246
247  if (led2OnH != 0) {
248    Alarm.free(led2OnAlarm);
249    Alarm.free(led2OffAlarm);
250  }
251
252  Alarm.free(co2OnAlarm);
253  Alarm.free(co2OffAlarm);
254
255  setAlarms();
256}
257
258void sendStatus() {
259  readSensors();
260
261  Serial.print("LOG");
262  Serial.print("||");
263  Serial.print(now());
264  Serial.print("||");
265  Serial.print(ledOn);
266  Serial.print("||");
267  Serial.print(ledAuto);
268  Serial.print("||");
269  Serial.print(led1OnH);
270  Serial.print(":");
271  Serial.print(led1OnM);
272  Serial.print("||");
273  Serial.print(led1OffH);
274  Serial.print(":");
275  Serial.print(led1OffM);
276  Serial.print("||");
277  Serial.print(led2OnH);
278  Serial.print(":");
279  Serial.print(led2OnM);
280  Serial.print("||");
281  Serial.print(led2OffH);
282  Serial.print(":");
283  Serial.print(led2OffM);
284  Serial.print("||");
285  Serial.print(co2On);
286  Serial.print("||");
287  Serial.print(co2Auto);
288  Serial.print("||");
289  Serial.print(co2OnH);
290  Serial.print(":");
291  Serial.print(co2OnM);
292  Serial.print("||");
293  Serial.print(co2OffH);
294  Serial.print(":");
295  Serial.print(co2OffM);
296  Serial.print("||");
297  Serial.print(ambientTemp);
298  Serial.print("||");
299  Serial.print(ambientHum);
300  Serial.print("||");
301  Serial.println(aquariumTemp);
302
303  Alarm.delay(500);
304  lcd.clear();
305  updateLcd();
306}
307
308// Function called once serial has recieved a key value  pair
309void setData() {
310  if (key == "") {
311    return;
312  }
313
314  bool  newStatus;
315  Serial.print(key);
316  Serial.println(value);
317
318  if ( key  == "led1OnH" ) {
319     led1OnH = value.toInt();
320     EEPROM.update(led1OnHAddress,  led1OnH);
321  }
322  else if ( key == "led1OffH" ) {
323     led1OffH = value.toInt();
324     EEPROM.update(led1OffHAddress, led1OffH);
325  }
326  else if ( key == "led1OnM"  ) {
327     led1OnM = value.toInt();
328     EEPROM.update(led1OnMAddress, led1OnM);
329  }
330  else if ( key == "led1OffM" ) {
331     led1OffM = value.toInt();
332     EEPROM.update(led1OffMAddress, led1OffM);
333  }
334  else if ( key == "led2OnH"  ) {
335     led2OnH = value.toInt();
336     EEPROM.update(led2OnHAddress, led2OnH);
337  }
338  else if ( key == "led2OffH" ) {
339     led2OffH = value.toInt();
340     EEPROM.update(led2OffHAddress, led2OffH);
341  }
342  else if ( key == "led2OnM"  ) {
343     led2OnM = value.toInt();
344     EEPROM.update(led2OnMAddress, led2OnM);
345  }
346  else if ( key == "led2OffM" ) {
347     led2OffM = value.toInt();
348     EEPROM.update(led2OffMAddress, led2OffM);
349  }
350  else  if ( key == "ledOn"  ) {
351     bool newStatus = value == "true";
352     if (ledOn != newStatus)  {
353      ledAuto = !ledAuto;
354     }
355
356     ledOn = newStatus;
357     updateRelay();
358  }
359  else if ( key == "co2On" ) {
360     bool newStatus = value == "true";
361     if (co2On != newStatus) {
362      co2Auto = !co2Auto;
363     }
364
365     co2On  = newStatus;
366     updateRelay();
367  }
368  else if ( key == "co2OnH" ) {
369     co2OnH = value.toInt();
370     EEPROM.update(co2OnHAddress, co2OnH);
371  }
372  else if ( key == "co2OffH" ) {
373     co2OffH = value.toInt();
374     EEPROM.update(co2OffHAddress,  co2OffH);
375  }
376  else if ( key == "co2OnM" ) {
377     co2OnM = value.toInt();
378     EEPROM.update(co2OnMAddress, co2OnM);
379  }
380  else if ( key == "co2OffM"  ) {
381     co2OffM = value.toInt();
382     EEPROM.update(co2OffMAddress, co2OffM);
383  }
384}
385
386void readSettingsFromMemory() {
387  led1OnH = EEPROM.read(led1OnHAddress);
388  led1OffH = EEPROM.read(led1OffHAddress);
389  led1OnM = EEPROM.read(led1OnMAddress);
390  led1OffM = EEPROM.read(led1OffMAddress);
391  led2OnH = EEPROM.read(led2OnHAddress);
392  led2OffH = EEPROM.read(led2OffHAddress);
393  led2OnM = EEPROM.read(led2OnMAddress);
394  led2OffM = EEPROM.read(led2OffMAddress);
395
396  co2OnH = EEPROM.read(co2OnHAddress);
397  co2OffH = EEPROM.read(co2OffHAddress);
398  co2OnM = EEPROM.read(co2OnMAddress);
399  co2OffM = EEPROM.read(co2OffMAddress);
400}
401
402void writeSettingsFromMemory()  {
403  EEPROM.write(led1OnHAddress, led1OnH);
404  EEPROM.write(led1OffHAddress,  led1OffH);
405  EEPROM.write(led1OnMAddress, led1OnM);
406  EEPROM.write(led1OffMAddress,  led1OffM);
407  EEPROM.write(led2OnHAddress, led2OnH);
408  EEPROM.write(led2OffHAddress,  led2OffH);
409  EEPROM.write(led2OnMAddress, led2OnM);
410  EEPROM.write(led2OffMAddress,  led2OffM);
411
412  EEPROM.write(co2OnHAddress, co2OnH);
413  EEPROM.write(co2OffHAddress,  co2OffH);
414  EEPROM.write(co2OnMAddress, co2OnM);
415  EEPROM.write(co2OffMAddress,  co2OffM);
416}
417
418
419void updateLedState() {
420  if (!ledAuto) {
421    return;
422  }
423  int h = hour();
424  int m = minute();
425
426  if (led1OnH > h || led2OffH  < h) {
427    ledOn = false;
428    return;
429  }
430
431  if (led1OffH < h &&  led2OnH > h) {
432    ledOn = false;
433    return;
434  }
435
436  if (led1OnH  == h && led1OnM > m ) {
437    ledOn = false;
438    return;
439  }
440
441  if  (led1OffH == h && led1OffM <= m ) {
442    ledOn = false;
443    return;
444  }
445
446  if (led2OnH == h && led2OnM > m ) {
447    ledOn = false;
448    return;
449  }
450
451  if (led2OffH == h && led2OffM <= m ) {
452    ledOn = false;
453    return;
454  }
455
456  ledOn = true;
457}
458
459void updateCo2State() {
460  if (!co2Auto)  {
461    return;
462  }
463
464  int h = hour();
465  int m = minute();
466
467  if (co2OnH > h || co2OffH < h) {
468    co2On = false;
469    return;
470  }
471
472  if (co2OnH == h && co2OnM > m ) {
473    co2On = false;
474    return;
475  }
476
477  if (co2OffH == h && co2OffM <= m ) {
478    co2On = false;
479    return;
480  }
481
482  co2On = true;
483}
484
485void toggleLed() {
486  ledOn = !ledOn;
487  ledAuto = !ledAuto;
488
489  updateRelay();
490  sendStatus();
491}
492
493void  toggleCo2() {
494  co2On = !co2On;
495  co2Auto = !co2Auto;
496
497  updateRelay();
498  sendStatus();
499}
500
501void updateLcd() {
502  if (lcdPage == 1) {
503    updateLcdPage1();
504  } else if (lcdPage == 2) {
505    updateLcdPage2();
506  } else if (lcdPage ==  3) {
507    updateLcdPage3();
508  } else {
509    updateLcdPage0();
510  }
511}
512
513void  loopLcdPage(int val) {
514  int newPage = lcdPage + val;
515
516  if (newPage >  3) {
517    newPage = 0;
518  }
519
520  if (newPage < 0) {
521    newPage = 3;
522  }
523
524  lcdPage = newPage;
525  updateLcd();
526}
527
528void updateLcdPage0()  {
529  int h = hour();
530  int m = minute();
531
532  lcd.setCursor(0,0);
533  if  (h < 10) {
534    lcd.print(F("0"));
535  }
536  lcd.print(h);
537  lcd.print(":");
538  if (m < 10) {
539    lcd.print(F("0"));
540  }
541  lcd.print(m);
542  lcd.print(F("  | "));
543  lcd.print((int) ambientTemp);
544  lcd.write(byte(0));
545  lcd.print(F("  "));
546  lcd.print((int) ambientHum);
547  lcd.print(F("% "));
548  lcd.setCursor(0,1);
549  lcd.print(aquariumTemp);
550  lcd.write(byte(0));
551  lcd.print(F(" "));
552  lcd.print(ledOn);
553  lcd.print(F("-"));
554  if (ledAuto) {
555    lcd.print(F("A"));
556  } else {
557    lcd.print(F("M"));
558  }
559  lcd.print(F(" "));
560  lcd.print(co2On);
561  lcd.print(F("-"));
562  if (co2Auto) {
563    lcd.print(F("A"));
564  } else  {
565    lcd.print(F("M"));
566  }
567  lcd.print(F("  "));
568}
569
570void  updateLcdPage1() {
571  lcd.setCursor(0,0);
572  lcd.print(F("LED: "));
573  if  (ledOn) {
574    lcd.print(F("on "));
575  } else {
576    lcd.print(F("off"));
577  }
578
579  lcd.print(F(" | "));
580
581  if (ledAuto) {
582    lcd.print(F("auto  "));
583  } else {
584    lcd.print(F("user "));
585  }
586  lcd.setCursor(0,1);
587  lcd.print(F("CO2: "));
588  if (ledOn) {
589    lcd.print(F("on "));
590  }  else {
591    lcd.print(F("off"));
592  }
593
594  lcd.print(F(" | "));
595
596  if (co2Auto) {
597    lcd.print(F("auto "));
598  } else {
599    lcd.print(F("user  "));
600  }
601}
602
603void updateLcdPage2() {
604
605  lcd.setCursor(0,0);
606  lcd.print(F("LED: "));
607  if (led1OnH < 10) {
608    lcd.print(F("0"));
609  }
610  lcd.print(led1OnH);
611  lcd.print(":");
612  if (led1OnM < 10) {
613    lcd.print(F("0"));
614  }
615  lcd.print(led1OnM);
616  lcd.print(F("-"));
617  if (led1OffH < 10) {
618    lcd.print(F("0"));
619  }
620  lcd.print(led1OffH);
621  lcd.print(":");
622  if (led1OffM < 10) {
623    lcd.print(F("0"));
624  }
625  lcd.print(led1OffM);
626
627  lcd.setCursor(0,1);
628  lcd.print(F("     "));
629  if (led2OnH < 10) {
630    lcd.print(F("0"));
631  }
632  lcd.print(led2OnH);
633  lcd.print(":");
634  if (led2OnM < 10) {
635    lcd.print(F("0"));
636  }
637  lcd.print(led2OnM);
638  lcd.print(F("-"));
639  if (led2OffH < 10) {
640    lcd.print(F("0"));
641  }
642  lcd.print(led2OffH);
643  lcd.print(":");
644  if (led2OffM < 10) {
645    lcd.print(F("0"));
646  }
647  lcd.print(led2OffM);
648}
649
650void updateLcdPage3()  {
651  lcd.setCursor(0,0);
652  lcd.print(F("CO2: "));
653  if (co2OnH < 10) {
654    lcd.print(F("0"));
655  }
656  lcd.print(co2OnH);
657  lcd.print(":");
658  if (co2OnM < 10) {
659    lcd.print(F("0"));
660  }
661  lcd.print(co2OnM);
662  lcd.print(F("-"));
663  if (co2OffH < 10) {
664    lcd.print(F("0"));
665  }
666  lcd.print(co2OffH);
667  lcd.print(":");
668  if (co2OffM < 10) {
669    lcd.print(F("0"));
670  }
671  lcd.print(co2OffM);
672  lcd.setCursor(0,1);
673  lcd.print(F("                "));
674}
675
676void readSensors() {
677  ambientTemp  = dht.readTemperature();
678  ambientHum = dht.readHumidity();
679  sensors.requestTemperatures();
680  aquariumTemp = sensors.getTempCByIndex(0);
681}
682
683void updateRelay() {
684  if (ledOn) {
685    setRelayState(0, 1);
686  } else {
687    setRelayState(0,  0);
688  }
689
690  if (co2On) {
691    setRelayState(1, 1);
692  } else {
693    setRelayState(1,  0);
694  }
695}
696
697void setRelayState(int relay, int state) {
698  if (relay  == 1) digitalWrite(relayCo2, state);
699  if (relay == 0) digitalWrite(relayLed,  state);
700}
701
702// functions to be called when an alarm triggers:
703void LedOn(){
704  ledOn = true;
705  ledAuto = true;
706  updateRelay();
707  sendStatus();
708}
709
710void  LedOff(){
711  ledOn = false;
712  ledAuto = true;
713  updateRelay();
714  sendStatus();
715}
716
717void  Co2On(){
718  co2On = true;
719  co2Auto = true;
720  updateRelay();
721  sendStatus();
722}
723
724void  Co2Off(){
725  co2On = false;
726  co2Auto = true;
727  updateRelay();
728  sendStatus();
729}
730
731//  Returns RTC date time
732// Used to sync alarm library
733time_t getRTCTime() {
734  DateTime now = rtc.now();
735  Serial.println("Sync RTC time");
736  return  now.unixtime();
737}
738

#include "RTClib.h"
#include <Time.h>
#include <TimeAlarms.h>
#include  <DHT.h>
#include <OneWire.h> 
#include <DallasTemperature.h>
#include <LiquidCrystal.h>
#include  <EEPROM.h>
#include "IRremote.h"

// RTC
RTC_DS1307 rtc;

//  DHT humidity senzor
#define DHTPIN 10     // what pin we're connected to
#define  DHTTYPE DHT22   // DHT 22  (AM2302)
DHT dht(DHTPIN, DHTTYPE); //// Initialize  DHT sensor for normal 16mhz Arduino

// Water proof senzor DS18B20
#define  ONE_WIRE_BUS 13
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);

//  LCD screen
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
byte degSymbol[8] = {
  B11100,
  B10100,
  B11100,
  B00000,
  B00000,
  B00000,
  B00000,
};
int  lcdPage = 0;

// IR
int irPin = 6;
IRrecv irrecv(irPin);
decode_results  irResults;
long irKey = 0;

// Serial read globals
char rx_byte = 0;
String  key = "";
bool isKey = false;
String value = "";
bool isValue = false;

//  Aquarium LED default values
int led1OnH = 8;
int led1OnM = 30;
int led1OffH  = 12;
int led1OffM = 30;
int led2OnH = 18;
int led2OnM = 30;
int led2OffH  = 20;
int led2OffM = 0;

int led1OnHAddress = 0;
int led1OnMAddress  = 1;
int led1OffHAddress = 2;
int led1OffMAddress = 3;
int led2OnHAddress  = 4;
int led2OnMAddress = 5;
int led2OffHAddress = 6;
int led2OffMAddress  = 7;

// Aquarium CO2 default values
int co2OnH = 7;
int co2OnM = 0;
int  co2OffH = 21;
int co2OffM = 0;

int co2OnHAddress = 8;
int co2OnMAddress  = 9;
int co2OffHAddress = 10;
int co2OffMAddress = 11;

// Aquarium  options
bool ledAuto = true;
bool co2Auto = true;
bool co2On = false;
bool  ledOn = false;

// Aquarium status
float aquariumTemp;

// Ambient  status
float ambientTemp, ambientHum;

// Status send to DB every 15 mins
int  statusSendMinutes = 20;

// Alarms
AlarmID_t led1OnAlarm = 0;
AlarmID_t  led1OffAlarm = 0;
AlarmID_t led2OnAlarm = 0;
AlarmID_t led2OffAlarm = 0;
AlarmID_t  co2OnAlarm = 0;
AlarmID_t co2OffAlarm = 0;

// Relay pins
int relayLed  = 7;
int relayCo2 = 8;

void setup() {
  pinMode(relayLed, OUTPUT);
  pinMode(relayCo2, OUTPUT);

  // Use only without RTC
  // setTime(10,19,0,16,2,19);

  Serial.begin(9600);
  dht.begin();
  sensors.begin();

  lcd.createChar(0,  degSymbol);
  lcd.begin(16, 2);

  // Start Ir reciever
  irrecv.enableIRIn();  // Start the receiver

  if (! rtc.begin()) {
    Serial.println("Couldn't  find RTC");
    while (1);
  }

  if (! rtc.isrunning()) {
    Serial.println("RTC  is NOT running!");
  }

  // Sync time lib with RTC
  setSyncProvider(getRTCTime);
  setSyncInterval(60 * 60 * 4);

  // should run only once at initial setup
  // writeSettingsFromMemory();

  readSettingsFromMemory();
  updateLedState();
  updateCo2State();
  updateRelay();
  sendStatus();

  setAlarms();
  Alarm.timerRepeat(60 * statusSendMinutes, sendStatus);
  Alarm.timerRepeat(60,  updateLcd);
}

void loop() {
  while(Serial.available()){
    //  Read seril data and create key values pairs
    rx_byte = Serial.read();

    if (rx_byte != '\n') {
      if (rx_byte == '$') {
        isValue =  false;
        isKey = true;
        continue;
      }
      if (rx_byte  == '=') {
        isValue = true;
        isKey = false;
        continue;
      }
      if (rx_byte == '&') {
        setData();

        value  = "";
        key = "";
        isValue = false;
        isKey = false;
        continue;
      }

      if (!isKey) {
        value += rx_byte;
      } else {
        key += rx_byte;
      }
    } else {
      if  (isValue) {
        setData();

        if (key != "" && key != "ledOn"  && key != "co2On") {
          updateLedState();
          updateCo2State();
          updateAlarms();
          updateRelay();
        }
      }

      value = "";
      key = "";
      isKey = false;
      isValue  = false;
      sendStatus();
    }
  }

  // IR remote loop
  if  (irrecv.decode(&irResults)) {
    dumpIR(&irResults);

    irrecv.resume();  // Receive the next value
//    Serial.println(irKey, HEX);
//    Serial.println();

    if (irKey == 16720605) {
      toggleLed();
    } else if (irKey == 16712445)  {
      toggleCo2();
    } else if (irKey == 16724175) {
      loopLcdPage(-1);
    } else if (irKey == 16743045) {
      loopLcdPage(1);
    }
  }

  Alarm.delay(1000);
}

void dumpIR(decode_results *irResults) {
  int  count = irResults->rawlen;
  irKey = irResults->value;
}


void setAlarms()  {
  led1OnAlarm = Alarm.alarmRepeat(led1OnH, led1OnM, 20, LedOn);
  led1OffAlarm  = Alarm.alarmRepeat(led1OffH, led1OffM, 20, LedOff);

  if (led2OnH != 0)  {
    led2OnAlarm = Alarm.alarmRepeat(led2OnH, led2OnM, 20, LedOn);
    led2OffAlarm  = Alarm.alarmRepeat(led2OffH, led2OffM, 40, LedOff);
  }

  co2OnAlarm  = Alarm.alarmRepeat(co2OnH, co2OnM, 40, Co2On);
  co2OnAlarm = Alarm.alarmRepeat(co2OffH,  co2OffM, 40, Co2Off);
}

void updateAlarms() {
  Alarm.free(led1OnAlarm);
  Alarm.free(led1OffAlarm);

  if (led2OnH != 0) {
    Alarm.free(led2OnAlarm);
    Alarm.free(led2OffAlarm);
  }

  Alarm.free(co2OnAlarm);
  Alarm.free(co2OffAlarm);

  setAlarms();
}

void sendStatus() {
  readSensors();

  Serial.print("LOG");
  Serial.print("||");
  Serial.print(now());
  Serial.print("||");
  Serial.print(ledOn);
  Serial.print("||");
  Serial.print(ledAuto);
  Serial.print("||");
  Serial.print(led1OnH);
  Serial.print(":");
  Serial.print(led1OnM);
  Serial.print("||");
  Serial.print(led1OffH);
  Serial.print(":");
  Serial.print(led1OffM);
  Serial.print("||");
  Serial.print(led2OnH);
  Serial.print(":");
  Serial.print(led2OnM);
  Serial.print("||");
  Serial.print(led2OffH);
  Serial.print(":");
  Serial.print(led2OffM);
  Serial.print("||");
  Serial.print(co2On);
  Serial.print("||");
  Serial.print(co2Auto);
  Serial.print("||");
  Serial.print(co2OnH);
  Serial.print(":");
  Serial.print(co2OnM);
  Serial.print("||");
  Serial.print(co2OffH);
  Serial.print(":");
  Serial.print(co2OffM);
  Serial.print("||");
  Serial.print(ambientTemp);
  Serial.print("||");
  Serial.print(ambientHum);
  Serial.print("||");
  Serial.println(aquariumTemp);

  Alarm.delay(500);
  lcd.clear();
  updateLcd();
}

// Function called once serial has recieved a key value  pair
void setData() {
  if (key == "") {
    return;
  }

  bool  newStatus;
  Serial.print(key);
  Serial.println(value);

  if ( key  == "led1OnH" ) {
     led1OnH = value.toInt();
     EEPROM.update(led1OnHAddress,  led1OnH);
  }
  else if ( key == "led1OffH" ) {
     led1OffH = value.toInt();
     EEPROM.update(led1OffHAddress, led1OffH);
  }
  else if ( key == "led1OnM"  ) {
     led1OnM = value.toInt();
     EEPROM.update(led1OnMAddress, led1OnM);
  }
  else if ( key == "led1OffM" ) {
     led1OffM = value.toInt();
     EEPROM.update(led1OffMAddress, led1OffM);
  }
  else if ( key == "led2OnH"  ) {
     led2OnH = value.toInt();
     EEPROM.update(led2OnHAddress, led2OnH);
  }
  else if ( key == "led2OffH" ) {
     led2OffH = value.toInt();
     EEPROM.update(led2OffHAddress, led2OffH);
  }
  else if ( key == "led2OnM"  ) {
     led2OnM = value.toInt();
     EEPROM.update(led2OnMAddress, led2OnM);
  }
  else if ( key == "led2OffM" ) {
     led2OffM = value.toInt();
     EEPROM.update(led2OffMAddress, led2OffM);
  }
  else  if ( key == "ledOn"  ) {
     bool newStatus = value == "true";
     if (ledOn != newStatus)  {
      ledAuto = !ledAuto;
     }

     ledOn = newStatus;
     updateRelay();
  }
  else if ( key == "co2On" ) {
     bool newStatus = value == "true";
     if (co2On != newStatus) {
      co2Auto = !co2Auto;
     }

     co2On  = newStatus;
     updateRelay();
  }
  else if ( key == "co2OnH" ) {
     co2OnH = value.toInt();
     EEPROM.update(co2OnHAddress, co2OnH);
  }
  else if ( key == "co2OffH" ) {
     co2OffH = value.toInt();
     EEPROM.update(co2OffHAddress,  co2OffH);
  }
  else if ( key == "co2OnM" ) {
     co2OnM = value.toInt();
     EEPROM.update(co2OnMAddress, co2OnM);
  }
  else if ( key == "co2OffM"  ) {
     co2OffM = value.toInt();
     EEPROM.update(co2OffMAddress, co2OffM);
  }
}

void readSettingsFromMemory() {
  led1OnH = EEPROM.read(led1OnHAddress);
  led1OffH = EEPROM.read(led1OffHAddress);
  led1OnM = EEPROM.read(led1OnMAddress);
  led1OffM = EEPROM.read(led1OffMAddress);
  led2OnH = EEPROM.read(led2OnHAddress);
  led2OffH = EEPROM.read(led2OffHAddress);
  led2OnM = EEPROM.read(led2OnMAddress);
  led2OffM = EEPROM.read(led2OffMAddress);

  co2OnH = EEPROM.read(co2OnHAddress);
  co2OffH = EEPROM.read(co2OffHAddress);
  co2OnM = EEPROM.read(co2OnMAddress);
  co2OffM = EEPROM.read(co2OffMAddress);
}

void writeSettingsFromMemory()  {
  EEPROM.write(led1OnHAddress, led1OnH);
  EEPROM.write(led1OffHAddress,  led1OffH);
  EEPROM.write(led1OnMAddress, led1OnM);
  EEPROM.write(led1OffMAddress,  led1OffM);
  EEPROM.write(led2OnHAddress, led2OnH);
  EEPROM.write(led2OffHAddress,  led2OffH);
  EEPROM.write(led2OnMAddress, led2OnM);
  EEPROM.write(led2OffMAddress,  led2OffM);

  EEPROM.write(co2OnHAddress, co2OnH);
  EEPROM.write(co2OffHAddress,  co2OffH);
  EEPROM.write(co2OnMAddress, co2OnM);
  EEPROM.write(co2OffMAddress,  co2OffM);
}


void updateLedState() {
  if (!ledAuto) {
    return;
  }
  int h = hour();
  int m = minute();

  if (led1OnH > h || led2OffH  < h) {
    ledOn = false;
    return;
  }

  if (led1OffH < h &&  led2OnH > h) {
    ledOn = false;
    return;
  }

  if (led1OnH  == h && led1OnM > m ) {
    ledOn = false;
    return;
  }

  if  (led1OffH == h && led1OffM <= m ) {
    ledOn = false;
    return;
  }

  if (led2OnH == h && led2OnM > m ) {
    ledOn = false;
    return;
  }

  if (led2OffH == h && led2OffM <= m ) {
    ledOn = false;
    return;
  }

  ledOn = true;
}

void updateCo2State() {
  if (!co2Auto)  {
    return;
  }

  int h = hour();
  int m = minute();

  if (co2OnH > h || co2OffH < h) {
    co2On = false;
    return;
  }

  if (co2OnH == h && co2OnM > m ) {
    co2On = false;
    return;
  }

  if (co2OffH == h && co2OffM <= m ) {
    co2On = false;
    return;
  }

  co2On = true;
}

void toggleLed() {
  ledOn = !ledOn;
  ledAuto = !ledAuto;

  updateRelay();
  sendStatus();
}

void  toggleCo2() {
  co2On = !co2On;
  co2Auto = !co2Auto;

  updateRelay();
  sendStatus();
}

void updateLcd() {
  if (lcdPage == 1) {
    updateLcdPage1();
  } else if (lcdPage == 2) {
    updateLcdPage2();
  } else if (lcdPage ==  3) {
    updateLcdPage3();
  } else {
    updateLcdPage0();
  }
}

void  loopLcdPage(int val) {
  int newPage = lcdPage + val;

  if (newPage >  3) {
    newPage = 0;
  }

  if (newPage < 0) {
    newPage = 3;
  }

  lcdPage = newPage;
  updateLcd();
}

void updateLcdPage0()  {
  int h = hour();
  int m = minute();

  lcd.setCursor(0,0);
  if  (h < 10) {
    lcd.print(F("0"));
  }
  lcd.print(h);
  lcd.print(":");
  if (m < 10) {
    lcd.print(F("0"));
  }
  lcd.print(m);
  lcd.print(F("  | "));
  lcd.print((int) ambientTemp);
  lcd.write(byte(0));
  lcd.print(F("  "));
  lcd.print((int) ambientHum);
  lcd.print(F("% "));
  lcd.setCursor(0,1);
  lcd.print(aquariumTemp);
  lcd.write(byte(0));
  lcd.print(F(" "));
  lcd.print(ledOn);
  lcd.print(F("-"));
  if (ledAuto) {
    lcd.print(F("A"));
  } else {
    lcd.print(F("M"));
  }
  lcd.print(F(" "));
  lcd.print(co2On);
  lcd.print(F("-"));
  if (co2Auto) {
    lcd.print(F("A"));
  } else  {
    lcd.print(F("M"));
  }
  lcd.print(F("  "));
}

void  updateLcdPage1() {
  lcd.setCursor(0,0);
  lcd.print(F("LED: "));
  if  (ledOn) {
    lcd.print(F("on "));
  } else {
    lcd.print(F("off"));
  }

  lcd.print(F(" | "));

  if (ledAuto) {
    lcd.print(F("auto  "));
  } else {
    lcd.print(F("user "));
  }
  lcd.setCursor(0,1);
  lcd.print(F("CO2: "));
  if (ledOn) {
    lcd.print(F("on "));
  }  else {
    lcd.print(F("off"));
  }

  lcd.print(F(" | "));

  if (co2Auto) {
    lcd.print(F("auto "));
  } else {
    lcd.print(F("user  "));
  }
}

void updateLcdPage2() {

  lcd.setCursor(0,0);
  lcd.print(F("LED: "));
  if (led1OnH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led1OnH);
  lcd.print(":");
  if (led1OnM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led1OnM);
  lcd.print(F("-"));
  if (led1OffH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led1OffH);
  lcd.print(":");
  if (led1OffM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led1OffM);

  lcd.setCursor(0,1);
  lcd.print(F("     "));
  if (led2OnH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led2OnH);
  lcd.print(":");
  if (led2OnM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led2OnM);
  lcd.print(F("-"));
  if (led2OffH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led2OffH);
  lcd.print(":");
  if (led2OffM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(led2OffM);
}

void updateLcdPage3()  {
  lcd.setCursor(0,0);
  lcd.print(F("CO2: "));
  if (co2OnH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(co2OnH);
  lcd.print(":");
  if (co2OnM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(co2OnM);
  lcd.print(F("-"));
  if (co2OffH < 10) {
    lcd.print(F("0"));
  }
  lcd.print(co2OffH);
  lcd.print(":");
  if (co2OffM < 10) {
    lcd.print(F("0"));
  }
  lcd.print(co2OffM);
  lcd.setCursor(0,1);
  lcd.print(F("                "));
}

void readSensors() {
  ambientTemp  = dht.readTemperature();
  ambientHum = dht.readHumidity();
  sensors.requestTemperatures();
  aquariumTemp = sensors.getTempCByIndex(0);
}

void updateRelay() {
  if (ledOn) {
    setRelayState(0, 1);
  } else {
    setRelayState(0,  0);
  }

  if (co2On) {
    setRelayState(1, 1);
  } else {
    setRelayState(1,  0);
  }
}

void setRelayState(int relay, int state) {
  if (relay  == 1) digitalWrite(relayCo2, state);
  if (relay == 0) digitalWrite(relayLed,  state);
}

// functions to be called when an alarm triggers:
void LedOn(){
  ledOn = true;
  ledAuto = true;
  updateRelay();
  sendStatus();
}

void  LedOff(){
  ledOn = false;
  ledAuto = true;
  updateRelay();
  sendStatus();
}

void  Co2On(){
  co2On = true;
  co2Auto = true;
  updateRelay();
  sendStatus();
}

void  Co2Off(){
  co2On = false;
  co2Auto = true;
  updateRelay();
  sendStatus();
}

//  Returns RTC date time
// Used to sync alarm library
time_t getRTCTime() {
  DateTime now = rtc.now();
  Serial.println("Sync RTC time");
  return  now.unixtime();
}

Aquarium server

no description/ Read More

Latest commit to the master branch on Invalid date

Download as a zip

Downloadable files

Fritzing

Comments

Only logged in users can leave comments

mihaimascas

0 Followers

•

0 Projects

Intro

Trademarks & CopyrightsWhistleblowingDigital Services ActTerms of ServicePrivacy PolicySecurityCookie Settings

Report content